home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 2002 #3 / Amiga Plus CD - 2002 - No. 03.iso / AmigaPlus / Tools / AmigaSystem / DepthMenu / Install < prev    next >
Encoding:
Text File  |  2003-02-19  |  8.4 KB  |  210 lines

  1. ;
  2. ; DepthMenu install script
  3. ; Copyright (c) 2001-2003 Arkadiusz [Yak] Wahlig
  4. ;
  5. ; $VER: DepthMenu_Install 1.22 (19.12.2003) Arkadiusz [Yak] Wahlig
  6. ;
  7. ; Spanish translation by Javier de las Rivas.
  8.  
  9. (set #copyright "Copyright (c) 2001-2003 Arkadiusz [Yak] Wahlig")
  10.  
  11. (IF (= @LANGUAGE "english")
  12. (
  13.  (set #hello (cat "\n\n\n" @app-name "\n" #copyright "\n\n\n\nThis script will install DepthMenu program\non your hard-disk.") )
  14.  
  15.  (set #dir-question1 "Where should I install the program?")
  16.  (set #dir-question2 "A directory called 'DepthMenu' will be created there.")
  17.  (set #dir-help "Choose a directory, where the DepthMenu program should be installed. The installer will create a directory called 'DepthMenu', where all needed files will be copied.")
  18.  
  19.  (set #languages-question "Which catalogs should be installed?")
  20.  (set #languages-help "DepthMenu's built-in language in english. If you want it to use some other languale you got to choose it now and set it as prefered in your Locale preferences program after installation.")
  21.  
  22.  (set #docs-question "Which documentations should be installed?")
  23.  (set #docs-help "Program documentations are available in different languages. On this screen you can choose, which of them should be installed.")
  24.  
  25.  (set #wbstartup-question "\n\nDo you want to start DepthMenu at system startup?")
  26.  (set #wbstartup-positive "Yes (recomended)")
  27.  (set #wbstartup-negative "No")
  28.  (set #wbstartup-help "If you choose 'Yes', DepthMenu will be started at every system startup. You can always disable it by removing file START_DepthMenu.info from SYS:WBStartup drawer.\n\nIf you choose 'No' you can always enable this feature by placing file START_DepthMenu.info in SYS:WBStartup drawer. In this case you will find this file in DepthMenu's directory.")
  29.  
  30.  (set #start-question "\n\nDo you want to start DepthMenu now?")
  31.  (set #start-help "If you choose 'Yes', DepthMenu will be started and ready to work NOW.")
  32.  
  33.  (set #bye-install "\n\nInstallation successful finished!")
  34.  (set #bye-update "\n\nUpdate successful finished!")
  35.  (set #bye-thanks "\n\nThank you for installing DepthMenu.")
  36. ))
  37. (IF (= @LANGUAGE "polski")
  38. (
  39.  (set #hello (cat "\n\n\n" @app-name " " #app-ver "\n" #copyright "\n\n\n\nTen skrypt zainstaluje program DepthMenu\nna twoim dysku twardym.") )
  40.  
  41.  (set #dir-question1 "Gdzie mam zainstalowaê program?")
  42.  (set #dir-question2 "Zostanie tam stworzony katalog 'DepthMenu'.")
  43.  (set #dir-help "Wybierz katalog, w którym ma byê zainstalowany program. W katalogu, który wybierzesz stworzony zostanie podkatalog 'DepthMenu' a do niego zostanâ skopiowane wszystkie potrzebne pliki.")
  44.  
  45.  (set #languages-question "Które katalogi jëzykowe chcesz zainstalowaê?")
  46.  (set #languages-help "Program posiada wbudowany jëzyk angielski. Jeôli chcesz aby uûywaî innego jëzyka, zaznacz go na tym ekranie a póúniej ustaw jëzyk go jako preferowany w systemowych ustawieniach Locale.")
  47.  
  48.  (set #docs-question "Które wersje dokumentacji chcesz zainstalowaê?")
  49.  (set #docs-help "Program posiada róûne wersje jëzykowe dokumentacji. Na tym ekranie moûesz wybraê, które z nich majâ byê zainstalowane.")
  50.  
  51.  (set #wbstartup-question "\n\nCzy chcesz uruchamiaê program przy starcie systemu?")
  52.  (set #wbstartup-positive "Tak (zalecane)")
  53.  (set #wbstartup-negative "Nie")
  54.  (set #wbstartup-help "Jeôli wybierzesz 'Tak', DepthMenu bëdzie uruchamiany przy kaûdym starcie systemu. Z moûliwoôci tej moûna w kaûdej chwili zrezygnowaê poprzez poprzez wyrzucenie lub przeniesienie pliku START_DepthMenu.info z katalogu WBStartup.\n\nJeôli wybierzesz 'Nie' plik START_DepthMenu.info bëdzie skopiowany do katalogu z programem. Jeôli wiëc zdecydujesz sië na uruchamianie przy starcie systemu to musisz tylko przenieôê jen plik do katalogu WBStartup.")
  55.  
  56.  (set #start-question "\n\nCzy chcesz uruchomiê program teraz?")
  57.  (set #start-help "Jeôli wybierzesz 'Tak', DepthMenu bëdzie uruchomiony i gotowy do pracy w tej chwili.")
  58.  
  59.  (set #bye-install "\n\nInstalacja zakoïczona pomyôlnie!")
  60.  (set #bye-update "\n\nUpdate zakoïczony pomyôlnie!")
  61.  (set #bye-thanks "\n\nDziëkujë za zainstalowanie programu.")
  62. ))
  63. (IF (= @LANGUAGE "español")
  64. (
  65.  (set #hello (cat "\n\n\n" @app-name " " #app-ver "\n" #copyright "\n\n\n\nEste script instalará DepthMenu en su disco duro.") )
  66.  
  67.  (set #dir-question1 "¿Dónde desea instalar el programa?")
  68.  (set #dir-question2 "Se creará un directorio llamado 'DepthMenu'.")
  69.  (set #dir-help "Elija la ubicación donde desea instalar DepthMenu. La instalación creará un directorio llamado 'DepthMenu', donde copiará todos los ficheros necesarios.")
  70.  
  71.  (set #languages-question "¿Qué idiomas desea instalar?")
  72.  (set #languages-help "El idioma de DepthMenu por defecto es el inglés. Si desea usarlo en otro idioma ha de elegirlo ahora.")
  73.  
  74.  (set #docs-question "¿Qué documentación desea instalar?")
  75.  (set #docs-help "Existe la documentación en diferentes idiomas. Elija el/los idioma(s) a instalar.")
  76.  
  77.  (set #wbstartup-question "\n\n¿Desea iniciar DepthMenu al arrancar el equipo?")
  78.  (set #wbstartup-positive "Sí (recomendado)")
  79.  (set #wbstartup-negative "No")
  80.  (set #wbstartup-help "Si elige 'Sí', DepthMenu se iniciará siempre al arranque. Puede desactivarlo eliminado el icono 'START_DepthMenu.info' de 'SYS:WBStartup'.\n\nSi elige 'No' puede activar esta opción copiando el icono 'START_DepthMenu.info' en 'SYS:WBStartup'. Encontrará este icono en el directorio de DepthMenu.")
  81.  
  82.  (set #start-question "\n\n¿Desea iniciar DepthMenu ahora?")
  83.  (set #start-help "Si elige 'Sí', DepthMenu se ejecutará AHORA.")
  84.  
  85.  (set #bye-install"\n\¡Instalación finalizada con éxito!")
  86.  (set #bye-update "\n\n¡Actualización finalizada con éxito!")
  87.  (set #bye-thanks "\n\nGracias por instalar DepthMenu.")
  88. ))
  89.  
  90. ; powitanie
  91. (complete 0)
  92. (message #hello)
  93.  
  94. ; gdzie instalowac?
  95. (set #_dir
  96.  (askdir
  97.   (prompt (cat #dir-question1 " ") #dir-question2)
  98.   (help #dir-help)
  99.   (default "Work:")
  100.   (disk)
  101.  )
  102. )
  103.  
  104. ; tworzenie katalogu, rozpoznanie czy jest stara wersja (update)
  105. (complete 10)
  106. (set #_instdir (tackon #_dir "DepthMenu"))
  107. (set #_update 0)
  108. (if (exists #_instdir) (set #_update 1) (makedir #_instdir) )
  109.  
  110. ; kopiujemy ikone katalogu
  111. (copyfiles
  112.  (source "/DepthMenu.info")
  113.  (dest #_dir)
  114. )
  115.  
  116. ; kopiujemy pliki lokalizacyjne (z pytaniem ktore)
  117. (complete 20)
  118. (copyfiles
  119.  (source "Catalogs")
  120.  (dest (tackon #_instdir "Catalogs"))
  121.  (infos)
  122.  (pattern "~(#?.cd)")
  123.  (prompt #languages-question)
  124.  (help #languages-help)
  125.  (confirm)
  126. )
  127. (copyfiles (source "Catalogs") (dest (tackon #_instdir "Catalogs")) (pattern "#?.cd#?"))
  128. (copyfiles (source "Catalogs.info") (dest #_instdir))
  129.  
  130. ; kopiujemy dokumentacje (z pytaniem ktore)
  131. (complete 30)
  132. (copyfiles
  133.  (source "Docs")
  134.  (dest (tackon #_instdir "Docs"))
  135.  (infos)
  136.  (all)
  137.  (prompt #docs-question)
  138.  (help #docs-help)
  139.  (confirm)
  140. )
  141. (copyfiles (source "Docs.info") (dest #_instdir))
  142.  
  143. ; kopiujemy program (bez ikony)
  144. (complete 40)
  145. (copyfiles (source "DepthMenu") (dest #_instdir))
  146.  
  147. ; tworzymy katalog modulow
  148. (complete 50)
  149. (makedir (tackon #_instdir "Modules"))
  150. (copyfiles (source "Modules.info") (dest #_instdir))
  151.  
  152. ; ustawiamy defaulttool ikonki START_DepthMenu na wczesniej wybrana lokacje programu
  153. (complete 60)
  154. (tooltype (dest "InstallData/START_DepthMenu") (setdefaulttool (tackon #_instdir "DepthMenu")))
  155.  
  156. ; usuwamy bardzo stara wersje (kiedys DepthMenu bylo umieszczane w WBStartup)
  157. (complete 70)
  158. (if(exists "SYS:WBStartup/DepthMenu")
  159. (
  160.  (delete "SYS:WBStartup/DepthMenu")
  161.  (delete "SYS:WBStartup/DepthMenu.info")
  162. ))
  163.  
  164. ; tu wchodzimy jesli instalujemy pierwszy raz
  165. (if (= #_update 0)
  166. (
  167.  
  168. ; nie powinno tam tego byc, ale noz widelec
  169. (complete 75)
  170. (if(exists "SYS:WBStartup/START_DepthMenu.info")
  171. (
  172.  (delete "SYS:WBStartup/START_DepthMenu.info")
  173. ))
  174.  
  175. ; kopiujemy ikone programu
  176. (complete 80)
  177. (copyfiles (source "DepthMenu.info") (dest #_instdir))
  178.  
  179. ; pytamy sie o odpalanie z WBStartup i jesli tak to kopiujemy ikone
  180. ; jesli nie to kopiujemy ja do katalogu z programem (z plikiem readme)
  181. (complete 85)
  182. (if(askbool
  183.  (prompt #wbstartup-question)
  184.  (choices #wbstartup-positive #wbstartup-negative)
  185.  (help #wbstartup-help)
  186.  )
  187. (copyfiles (source "InstallData/START_DepthMenu.info") (dest "SYS:WBStartup"))
  188. (copyfiles (source "InstallData") (dest #_instdir) (infos) (pattern "START_DepthMenu#?"))
  189. )
  190.  
  191. ))
  192.  
  193. ; pytamy sie o odpalenie programu teraz i odpalamy jesli tak
  194. (complete 90)
  195. (if(askbool
  196.  (prompt #start-question)
  197.  (help #start-help)
  198.  )
  199. (
  200.  (run "InstallData/BreakDM")
  201.  (run (cat "Run <>NIL: " (tackon #_instdir "DepthMenu")))
  202. ))
  203.  
  204. ; kilka slow na pozegnanie z installerem
  205. (complete 100)
  206. (if (= #_update 0)
  207.  (exit (cat #bye-install #bye-thanks) (quiet) )
  208.  (exit (cat #bye-update #bye-thanks) (quiet) )
  209. )
  210.